home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / The World of Computer Software.iso / cmsrc392.zip / CSC.MF < prev    next >
Text File  |  1992-03-30  |  3KB  |  71 lines
  1. % Caps and Small Caps in Computer Modern Roman
  2.  
  3. font_coding_scheme:=if ligs=0: "TeX typewriter text"
  4.  else: "TeX text without f-ligatures" fi;
  5. spanish_shriek=oct"016"; spanish_query=oct"017";
  6.  
  7. mode_setup; font_setup;
  8. input romanu;  % upper case (majuscules)
  9. input greeku;  % upper case greek letters
  10. input romand;  % numerals
  11. input romanp;  % ampersand, question marks, currency sign
  12. input romspu;  % uppercase specials (\AE, \OE, \O)
  13. input punct;  % punctuation symbols common to all roman and italic
  14. input accent;  % accents common to roman and italic text
  15. input romsub;  % substitutes for ligatures
  16. if ligs>0: input comlig; fi  % ligatures common with italic
  17.  
  18. ligtable "!": "`" =: spanish_shriek;
  19. ligtable "?": "`" =: spanish_query;
  20. font_slant slant; font_x_height x_height#;
  21. if monospace: font_normal_space 9u#; % no stretching or shrinking
  22.  font_quad 18u#;
  23.  font_extra_space 9u#;
  24. else: font_normal_space 6u#+2letter_fit#;
  25.  font_normal_stretch 3u#; font_normal_shrink 2u#;
  26.  font_quad 18u#+4letter_fit#;
  27.  font_extra_space 2u#;
  28.  k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
  29.  ligtable "P": "T": "Y": "a" kern kk#, "A" kern kk#;
  30.  ligtable "F": "V": "W": if serifs: "a" kern kkk#, "A" kern kkk#,
  31.   else: "a" kern kk#, "A" kern kk#, fi
  32.   "K": "X": "o" kern k#, "O" kern k#, "c" kern k#, "C" kern k#,
  33.    "g" kern k#, "G" kern k#, "q" kern k#, "Q" kern k#;
  34.  ligtable "O": "D": "x" kern k#, "X" kern k#, "w" kern k#, "W" kern k#,
  35.    "a" kern k#, "A" kern k#, "v" kern k#, "V" kern k#, "y" kern k#, "Y" kern k#;
  36.  ligtable "A": if serifs: "R": fi "c" kern k#, "C" kern k#,
  37.    "o" kern k#, "O" kern k#, "g" kern k#, "G" kern k#,
  38.    "u" kern k#, "U" kern k#, "q" kern k#, "Q" kern k#,
  39.   "L": "T" kern kk#, "t" kern kk#, "Y" kern kk#, "y" kern kk#,
  40.    "V" kern kkk#, "v" kern kkk#, "W" kern kkk#, "w" kern kkk#;
  41.  ligtable "I": "I" kern -k#; fi % Richard III
  42. % ligature programs for |"-"|, |"`"|, and |"'"| are in the {\tt comlig} file
  43.  
  44. %%% fine lower
  45. forsuffixes $= u, width_adj, cap_serif_fit, letter_fit,
  46.  body_height, cap_height, x_height, bar_height, comma_depth,
  47.  flare, cap_hair, stem, cap_stem, cap_curve, cap_ess,
  48.  cap_jut, beak_jut, beak, slab, cap_bar, cap_band, cap_notch_cut,
  49.  o, apex_o:  $.#:=lower.$.#; endfor
  50. fudge:=lower.fudge;
  51. font_setup; % now try again with |lower| settings
  52. extra_endchar:=extra_endchar&"charcode:=charcode+code_offset";
  53. code_offset:=ASCII"a" - ASCII"A";
  54. input romanu;  % majuscules (in lowercase positions)
  55. code_offset:=-3;
  56. input romspu;  % \AE, \OE, \O\ (in positions of \ae, \oe, \o)
  57. code_offset:=0;
  58. input cscspu;  % substitutes for the remaining characters of romspl
  59. if not monospace:
  60.  k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
  61.  ligtable "p": "t": "y": "a" kern kk#;
  62.  ligtable "f": "v": "w": "a" kern if serifs: kkk# else: kk#\\fi,
  63.   "k": "x": "o" kern k#, "c" kern k#, "g" kern k#, "q" kern k#;
  64.  ligtable "o": "d": "x" kern k#, "w" kern k#, "a" kern k#,
  65.    "v" kern k#, "y" kern k#;
  66.  ligtable "a": if serifs: "r": fi "c" kern k#, "o" kern k#,
  67.    "g" kern k#, "u" kern k#, "q" kern k#,
  68.   "l": "'" kern kk#, "t" kern kk#, "y" kern kk#, "v" kern kkk#, "w" kern kkk#;
  69.  ligtable "i": "i" kern -k#; fi % skiing
  70. bye.
  71.